ReceiveExample.cpp

Go to the documentation of this file.

 
#include "YmodemCore.h"
#include <Arduino.h>
#include <HardwareSerial.h>
#include <SPIFFS.h>
#include <Update.h>
 
// Define CONFIG_SPIFFS_SIZE with an appropriate value
#define CONFIG_SPIFFS_SIZE (2 * 1024 * 1024)        
#define MAX_FILE_SIZE (CONFIG_SPIFFS_SIZE - 0x2000) 
#define FIRMWARE_UPDATE                             
Ymodem ymodem; 
void setup()
{
  // Initialize Serial for debugging
  Serial.begin(115200);
  while (!Serial) {
    ; // Wait until Serial is ready
  }
 
  // Initialize SPIFFS
  if (!SPIFFS.begin(true)) {
    Serial.println("Error mounting SPIFFS");
    return;
  }
 
  // Configure the YModem activity LED pin
  pinMode(YMODEM_LED_ACT, OUTPUT);
  digitalWrite(YMODEM_LED_ACT, YMODEM_LED_ACT_ON ^ 1);
 
  // Configure UART (Serial1)
  Serial1.begin(115200, SERIAL_8N1, 16, 17); // RX, TX pins
  if (!Serial1) {
    log_e("Error initializing Serial1");
    return;
  }
 
  // Setup complete message
  log_i("Setup complete. Ready to receive files.");
}
 
void loop()
{
  static int nfile = 1;
  char       fname[128];
  char       orig_name[256];
  uint32_t   max_fsize;
  int        rec_res = -1;
 
  // ==== File reception ====
  max_fsize = SPIFFS.totalBytes() - SPIFFS.usedBytes();
  if (max_fsize > 16 * 1024) {
    if (max_fsize > MAX_FILE_SIZE) {
      max_fsize = MAX_FILE_SIZE;
    }
 
    sprintf(fname, "/firmware-%d.bin", nfile);
    File ffd = SPIFFS.open(fname, FILE_WRITE);
    if (ffd) {
      Serial.println("\r\nReceiving file, start YModem transfer on the host...\r\n");
      rec_res = ymodem.receive(ffd, max_fsize, orig_name);
      ffd.close();
      Serial.println("\r\n");
 
      if (rec_res > 0) {
        log_i("Transfer complete. Size=%d, Original name: \"%s\"", rec_res, fname);
 
#ifdef FIRMWARE_UPDATE
        // ==== Load the binary to the ESP32 ====
        File bin_file = SPIFFS.open(fname, FILE_READ);
        if (bin_file) {
          size_t bin_size = bin_file.size();
          if (Update.begin(bin_size)) {
            log_d("Starting OTA update...");
            size_t written = Update.writeStream(bin_file);
            if (written == bin_size)
              log_i("Write complete.");
            else
              log_w("Incomplete write. Only %d of %d bytes written", written, bin_size);
 
            if (Update.end()) {
              if (Update.isFinished()) {
                log_i("OTA update complete. Restarting...");
                while (1) {
                  digitalWrite(YMODEM_LED_ACT, YMODEM_LED_ACT_ON ^ 1);
                  vTaskDelay(100);
                }
              }
              else
                log_e("OTA update not complete.");
            }
            else
              log_e("Error in OTA update: %s", Update.errorString());
          }
          else
            log_e("Could not start OTA update.");
          bin_file.close();
        }
        else
          log_e("Error opening binary file \"%s\" for OTA.", fname);
#endif
      }
      else {
        log_e("Transfer error. Error code=%d", rec_res);
        SPIFFS.remove(fname);
      }
    }
    else
      log_e("Error opening file \"%s\" for receiving.", fname);
 
    delay(1000);
  }
  else {
    log_e("Filesystem full. Remaining space: %u bytes", max_fsize);
  }
 
  delay(10);
}